add missing vector methods (#206)

* add missing vector methods

* fix pop!

* add vector method tests

* add tests for inplace vector methods

* bump version number

Author: Pietro Vertechi

Project.toml

@@ -1,6 +1,6 @@
 name = "StructArrays"
 uuid = "09ab397b-f2b6-538f-b94a-2f83cf4a842a"
-version = "0.6.3"
+version = "0.6.4"
 
 [deps]
 Adapt = "79e6a3ab-5dfb-504d-930d-738a2a938a0e"

src/structarray.jl

@@ -362,21 +362,37 @@ Base.@propagate_inbounds function Base.setindex!(s::StructArray{<:Any, <:Any, <:
     s
 end
 
-function Base.push!(s::StructVector, vals)
-    foreachfield(push!, s, vals)
-    return s
+for f in (:push!, :pushfirst!)
+    @eval function Base.$f(s::StructVector, vals)
+        foreachfield($f, s, vals)
+        return s
+    end
 end
 
-function Base.pop!(s::StructVector{T}) where T
-    t = map(pop!, components(s))
-    return createinstance(T, t...)
+for f in (:append!, :prepend!)
+    @eval function Base.$f(s::StructVector, vals::StructVector)
+        foreachfield($f, s, vals)
+        return s
+    end
 end
 
-function Base.append!(s::StructVector, vals::StructVector)
-    foreachfield(append!, s, vals)
+function Base.insert!(s::StructVector, i::Integer, vals)
+    foreachfield((v, val) -> insert!(v, i, val), s, vals)
     return s
 end
 
+for f in (:pop!, :popfirst!)
+    @eval function Base.$f(s::StructVector{T}) where T
+        t = map($f, components(s))
+        return createinstance(T, t...)
+    end
+end
+
+function Base.deleteat!(s::StructVector{T}, idxs) where T
+    t = map(Base.Fix2(deleteat!, idxs), components(s))
+    return StructVector{T}(t)
+end
+
 Base.copyto!(I::StructArray, J::StructArray) = (foreachfield(copyto!, I, J); I)
 
 function Base.copyto!(I::StructArray, doffs::Integer, J::StructArray, soffs::Integer, n::Integer)

src/tables.jl

@@ -21,16 +21,18 @@ function try_compatible_columns(rows::R, s::StructArray) where {R}
     return Tables.columntable(rows)
 end
 
-function Base.append!(s::StructVector, rows)
-    table = try_compatible_columns(rows, s)
-    if table !== nothing
-        # Input `rows` is a container of rows _and_ satisfies column
-        # table interface.  Thus, we can add the input column-by-column.
-        foreachfield(append!, s, table)
-        return s
-    else
-        # Otherwise, fallback to a generic implementation expecting
-        # that `rows` is an iterator:
-        return foldl(push!, rows; init = s)
+for (f, g) in zip((:append!, :prepend!), (:push!, :pushfirst!))
+    @eval function Base.$f(s::StructVector, rows)
+        table = try_compatible_columns(rows, s)
+        if table !== nothing
+            # Input `rows` is a container of rows _and_ satisfies column
+            # table interface.  Thus, we can add the input column-by-column.
+            foreachfield($f, s, table)
+            return s
+        else
+            # Otherwise, fallback to a generic implementation expecting
+            # that `rows` is an iterator:
+            return foldl($g, rows; init = s)
+        end
     end
 end

test/runtests.jl

@@ -161,6 +161,86 @@ end
     @test c == d
 end
 
+struct C
+    a::Int
+    b::Int
+    c::String
+end
+
+@testset "in-place vector methods" begin
+    c = StructArray(a=[1], b=[2], c=["a"])
+    push!(c, (a=10, b=20, c="A"))
+    @test c == StructArray(a=[1,10], b=[2,20], c=["a","A"])
+    @test pop!(c) == (a=10, b=20, c="A")
+    @test c == StructArray(a=[1], b=[2], c=["a"])
+
+    c = StructArray(a=[1], b=[2], c=["a"])
+    pushfirst!(c, (a=10, b=20, c="A"))
+    @test c == StructArray(a=[10,1], b=[20,2], c=["A","a"])
+    @test popfirst!(c) == (a=10, b=20, c="A")
+    @test c == StructArray(a=[1], b=[2], c=["a"])
+
+    c = StructArray(a=[1,2,3], b=[2,3,4], c=["a","b","c"])
+    d = insert!(c, 2, (a=10, b=20, c="A"))
+    @test d == c == StructArray(a=[1,10,2,3], b=[2,20,3,4], c=["a","A","b","c"])
+    d = deleteat!(c, 2)
+    @test d == c == StructArray(a=[1,2,3], b=[2,3,4], c=["a","b","c"])
+
+    c = StructArray(a=[1], b=[2], c=["a"])
+    d = [(a=10, b=20, c="A")]
+    e = append!(c, d)
+
+    @test e == c == StructArray(a=[1,10], b=[2,20], c=["a","A"])
+
+    c = StructArray(a=[1], b=[2], c=["a"])
+    d = [(a=10, b=20, c="A")]
+    e = prepend!(c, d)
+
+    @test e == c == StructArray(a=[10,1], b=[20,2], c=["A","a"])
+
+    c = StructArray(a=[1,2,3], b=[1,4,6], c=["a","b","c"])
+    d = filter!(c) do el
+        return isodd(el.a) && iseven(el.b)
+    end
+    @test d == c == StructArray(a=[3], b=[6], c=["c"])
+
+    c = StructArray{C}(a=[1], b=[2], c=["a"])
+    push!(c, C(10, 20, "A"))
+    @test c == StructArray{C}(a=[1,10], b=[2,20], c=["a","A"])
+    @test pop!(c) == C(10, 20, "A")
+    @test c == StructArray{C}(a=[1], b=[2], c=["a"])
+
+    c = StructArray{C}(a=[1], b=[2], c=["a"])
+    pushfirst!(c, C(10, 20, "A"))
+    @test c == StructArray{C}(a=[10,1], b=[20,2], c=["A","a"])
+    @test popfirst!(c) == C(10, 20, "A")
+    @test c == StructArray{C}(a=[1], b=[2], c=["a"])
+
+    c = StructArray{C}(a=[1,2,3], b=[2,3,4], c=["a","b","c"])
+    d = insert!(c, 2, C(10, 20, "A"))
+    @test d == c == StructArray{C}(a=[1,10,2,3], b=[2,20,3,4], c=["a","A","b","c"])
+    d = deleteat!(c, 2)
+    @test d == c == StructArray{C}(a=[1,2,3], b=[2,3,4], c=["a","b","c"])
+
+    c = StructArray{C}(a=[1], b=[2], c=["a"])
+    d = [C(10, 20, "A")]
+    e = append!(c, d)
+
+    @test e == c == StructArray{C}(a=[1,10], b=[2,20], c=["a","A"])
+
+    c = StructArray{C}(a=[1], b=[2], c=["a"])
+    d = [C(10, 20, "A")]
+    e = prepend!(c, d)
+
+    @test e == c == StructArray{C}(a=[10,1], b=[20,2], c=["A","a"])
+
+    c = StructArray{C}(a=[1,2,3], b=[1,4,6], c=["a","b","c"])
+    d = filter!(c) do el
+        return isodd(el.a) && iseven(el.b)
+    end
+    @test d == c == StructArray{C}(a=[3], b=[6], c=["c"])
+end
+
 @testset "iterators" begin
     c = [1, 2, 3, 1, 1]
     d = StructArrays.GroupPerm(c)