add rand(::Tuple)

Author: rfourquet

stdlib/Random/src/generation.jl

@@ -429,3 +429,53 @@ function rand(rng::AbstractRNG, sp::SamplerSimple{<:AbstractString,<:Sampler})::
         isvalid_unsafe(str, pos) && return str[pos]
     end
 end
+
+
+## random elements from tuples
+
+### 1
+
+Sampler(::AbstractRNG, t::Tuple{A}, ::Repetition) where {A} =
+    SamplerTrivial(t)
+
+rand(rng::AbstractRNG, sp::SamplerTrivial{Tuple{A}}) where {A} =
+    @inbounds return sp[][1]
+
+### 2
+
+Sampler(rng::AbstractRNG, t::Tuple{A,B}, n::Repetition) where {A,B} =
+    SamplerSimple(t, Sampler(rng, Bool, n))
+
+rand(rng::AbstractRNG, sp::SamplerSimple{Tuple{A,B}}) where {A,B} =
+    @inbounds return sp[][1 + rand(rng, sp.data)]
+
+### 3
+
+Sampler(rng::AbstractRNG, t::Tuple{A,B,C}, n::Repetition) where {A,B,C} =
+    SamplerSimple(t, Sampler(rng, UInt52(), n))
+
+function rand(rng::AbstractRNG, sp::SamplerSimple{Tuple{A,B,C}}) where {A,B,C}
+    local r
+    while true
+        r = rand(rng, sp.data)
+        r != 0x000fffffffffffff && break
+    end
+    @inbounds return sp[][1 + r ÷ 0x0005555555555555]
+end
+
+### 4
+Sampler(rng::AbstractRNG, t::Tuple{A,B,C,D}, n::Repetition) where {A,B,C,D} =
+    SamplerSimple(t, Sampler(rng, UInt52(), n))
+
+function rand(rng::AbstractRNG, sp::SamplerSimple{Tuple{A,B,C,D}}) where {A,B,C,D}
+    r = rand(rng, UInt52Raw(Int)) & 3
+    @inbounds return sp[][1 + r]
+end
+
+### n
+
+Sampler(rng::AbstractRNG, t::Tuple, n::Repetition) =
+    SamplerSimple(t, Sampler(rng, Base.OneTo(length(t)), n))
+
+rand(rng::AbstractRNG, sp::SamplerSimple{<:Tuple}) =
+    @inbounds return sp[][rand(rng, sp.data)]

stdlib/Random/test/runtests.jl

@@ -672,3 +672,12 @@ end
     r = T(1):T(108)
     @test rand(RNG, SamplerRangeFast(r)) ∈ r
 end
+
+@testset "rand(::Tuple)" begin
+    @test rand((0x1,)) == 0x1
+    @test rand((0x1, 2)) ∈ 1:2
+    @test rand((0x1, 2, 3)) ∈ 1:3
+    @test rand((0x1, 2, 3, 4)) ∈ 1:4
+    @test rand((0x1, 2, 3, 4, 5)) ∈ 1:5
+    @test rand((0x1, 2, 3, 4, 6)) ∈ 1:6
+end