Fix precompiled resource bundle warnings

For SPM modules that use precompiled resource bundles (i.e `.bundle` files), Bazel throws the warning
```
WARNING: input 'Sources/Down/Resources/DownView (macOS).bundle' is a directory; dependency checking of directories is unsound
```

Instead of just referencing the `.bundle` path directly we should wrap it in a `apple_bundle_import` for the prebuilt bundle and then add it into the `resources` attr.

Author: sebastianv1

swiftpkg/internal/swiftpkg_build_files.bzl

@@ -727,6 +727,9 @@ expected: {expected}\
 
 # MARK: - Apple Resource Group
 
+def _sanitized_bundle_file_name(bundle_path):
+    return bundle_path.replace(" ", "_").replace(".", "_").replace("(", "_").replace(")", "_")
+
 def _apple_resource_bundle(target, package_name, default_localization, expose_build_targets):
     bzl_target_name = pkginfo_targets.bazel_label_name(target)
     bundle_label_name = pkginfo_targets.resource_bundle_label_name(bzl_target_name)
@@ -735,10 +738,21 @@ def _apple_resource_bundle(target, package_name, default_localization, expose_bu
         bzl_target_name,
     )
 
-    resources = sorted([
+    sorted_resources = sorted([
         r.path
         for r in target.resources
     ])
+    resources = [
+        r
+        for r in sorted_resources
+        if not r.endswith(".bundle")
+    ]
+    precompiled_bundles_and_labels = [
+        (r, "{}_{}".format(bundle_label_name, _sanitized_bundle_file_name(r.split("/")[-1])))
+        for r in sorted_resources
+        if r.endswith(".bundle")
+    ]
+    precompiled_bundle_resource_labels = [bundle_pair[1] for bundle_pair in precompiled_bundles_and_labels]
 
     load_stmts = [
         apple_resource_bundle_load_stmt,
@@ -760,11 +774,28 @@ def _apple_resource_bundle(target, package_name, default_localization, expose_bu
                 "infoplists": [":{}".format(infoplist_name)],
                 # Based upon the code in SPM, it looks like they only support unstructured resources.
                 # https://github.com/apple/swift-package-manager/blob/main/Sources/PackageModel/Resource.swift#L25-L33
-                "resources": resources,
+                "resources": resources + [":{}".format(bundle_label) for bundle_label in precompiled_bundle_resource_labels],
                 "visibility": _target_visibility(expose_build_targets),
             },
         ),
     ]
+
+    if len(precompiled_bundles_and_labels) > 0:
+        load_stmts.append(apple_resource_bundle_import_load_stmt)
+        for precompiled_bundle, precompiled_bundle_label_name in precompiled_bundles_and_labels:
+            decls.append(
+                build_decls.new(
+                    kind = apple_kinds.apple_bundle_import,
+                    name = precompiled_bundle_label_name,
+                    attrs = {
+                        "bundle_imports": scg.new_fn_call(
+                            "glob",
+                            ["{precompiled_bundle}/**/*".format(precompiled_bundle = precompiled_bundle)],
+                        ),
+                    },
+                ),
+            )
+
     return struct(
         bundle_name = bundle_name,
         bundle_label_name = bundle_label_name,
@@ -1135,6 +1166,7 @@ apple_kinds = struct(
     static_xcframework_import = "apple_static_xcframework_import",
     dynamic_xcframework_import = "apple_dynamic_xcframework_import",
     resource_bundle = "apple_resource_bundle",
+    apple_bundle_import = "apple_bundle_import",
 )
 
 apple_apple_location = "@build_bazel_rules_apple//apple:apple.bzl"
@@ -1156,6 +1188,11 @@ apple_resource_bundle_load_stmt = load_statements.new(
     apple_kinds.resource_bundle,
 )
 
+apple_resource_bundle_import_load_stmt = load_statements.new(
+    apple_resources_location,
+    apple_kinds.apple_bundle_import,
+)
+
 swiftpkg_kinds = struct(
     generate_modulemap = "generate_modulemap",
     objc_resource_bundle_accessor_hdr = "objc_resource_bundle_accessor_hdr",

swiftpkg/tests/swiftpkg_build_files_tests.bzl

@@ -437,6 +437,33 @@ def _pkg_info(
                 repo_name = _repo_name,
                 swift_src_info = pkginfos.new_swift_src_info(),
             ),
+            pkginfos.new_target(
+                name = "SwiftLibraryWithPrecompiledBundleResource",
+                type = "regular",
+                c99name = "SwiftLibraryWithPrecompiledBundleResource",
+                module_type = "SwiftTarget",
+                path = "Source/SwiftLibraryWithPrecompiledBundleResource",
+                sources = [
+                    "SwiftLibraryWithPrecompiledBundleResource.swift",
+                ],
+                resources = [
+                    pkginfos.new_resource(
+                        path = "Source/SwiftLibraryWithPrecompiledBundleResource/Resources/PrecompiledResources.bundle",
+                        rule = pkginfos.new_resource_rule(
+                            process = pkginfos.new_resource_rule_process(),
+                        ),
+                    ),
+                    pkginfos.new_resource(
+                        path = "Source/SwiftLibraryWithPrecompiledBundleResource/Resources/chicken.json",
+                        rule = pkginfos.new_resource_rule(
+                            process = pkginfos.new_resource_rule_process(),
+                        ),
+                    ),
+                ],
+                dependencies = [],
+                repo_name = _repo_name,
+                swift_src_info = pkginfos.new_swift_src_info(),
+            ),
             pkginfos.new_target(
                 name = "ObjcLibraryWithResources",
                 type = "regular",
@@ -958,6 +985,62 @@ swift_library(
     tags = ["manual"],
     visibility = ["//:__subpackages__"],
 )
+""",
+        ),
+        struct(
+            msg = "Swift library target with precompiled bundle resource.",
+            name = "SwiftLibraryWithPrecompiledBundleResource",
+            pkg_info = _pkg_info(),
+            exp = """\
+load("@build_bazel_rules_apple//apple:resources.bzl", "apple_bundle_import", "apple_resource_bundle")
+load("@build_bazel_rules_swift//swift:swift.bzl", "swift_library")
+load("@rules_swift_package_manager//swiftpkg:build_defs.bzl", "resource_bundle_accessor", "resource_bundle_infoplist")
+
+apple_bundle_import(
+    name = "SwiftLibraryWithPrecompiledBundleResource.rspm_resource_bundle_PrecompiledResources_bundle",
+    bundle_imports = glob(["Source/SwiftLibraryWithPrecompiledBundleResource/Resources/PrecompiledResources.bundle/**/*"]),
+)
+
+apple_resource_bundle(
+    name = "SwiftLibraryWithPrecompiledBundleResource.rspm_resource_bundle",
+    bundle_name = "MyPackage_SwiftLibraryWithPrecompiledBundleResource",
+    infoplists = [":SwiftLibraryWithPrecompiledBundleResource.rspm_resource_bundle_infoplist"],
+    resources = [
+        "Source/SwiftLibraryWithPrecompiledBundleResource/Resources/chicken.json",
+        ":SwiftLibraryWithPrecompiledBundleResource.rspm_resource_bundle_PrecompiledResources_bundle",
+    ],
+    visibility = ["//:__subpackages__"],
+)
+
+resource_bundle_accessor(
+    name = "SwiftLibraryWithPrecompiledBundleResource.rspm_resource_bundle_accessor",
+    bundle_name = "MyPackage_SwiftLibraryWithPrecompiledBundleResource",
+)
+
+resource_bundle_infoplist(
+    name = "SwiftLibraryWithPrecompiledBundleResource.rspm_resource_bundle_infoplist",
+    region = "en",
+)
+
+swift_library(
+    name = "SwiftLibraryWithPrecompiledBundleResource.rspm",
+    always_include_developer_search_paths = True,
+    alwayslink = True,
+    copts = [
+        "-DSWIFT_PACKAGE",
+        "-Xcc",
+        "-DSWIFT_PACKAGE",
+    ],
+    data = [":SwiftLibraryWithPrecompiledBundleResource.rspm_resource_bundle"],
+    module_name = "SwiftLibraryWithPrecompiledBundleResource",
+    package_name = "MyPackage",
+    srcs = [
+        "Source/SwiftLibraryWithPrecompiledBundleResource/SwiftLibraryWithPrecompiledBundleResource.swift",
+        ":SwiftLibraryWithPrecompiledBundleResource.rspm_resource_bundle_accessor",
+    ],
+    tags = ["manual"],
+    visibility = ["//:__subpackages__"],
+)
 """,
         ),
         struct(