Day 2

Author: glguy

.ghcid

@@ -1 +1 @@
---command="cabal v2-repl --repl-options=-fno-code --repl-options=-fno-break-on-exception --repl-options=-fno-break-on-error --repl-options=-v1 --repl-options=-ferror-spans --repl-options=-j --repl-options=-Wall"
+--command="cabal v2-repl --repl-options=-fno-break-on-exception --repl-options=-fno-break-on-error --repl-options=-v1 --repl-options=-ferror-spans --repl-options=-j --repl-options=-Wall"

advent2019.cabal

@@ -34,3 +34,9 @@ executable Day01
   build-depends:       advent2019, base,
   hs-source-dirs:      execs
   default-language:    Haskell2010
+
+executable Day02
+  main-is:             Day02.hs
+  build-depends:       advent2019, base, containers
+  hs-source-dirs:      execs
+  default-language:    Haskell2010

common/Advent.hs

@@ -1,13 +1,13 @@
 module Advent
   ( module Advent
-  , satisfy, anySingle
+  , satisfy, anySingle, sepBy
   ) where
 
 import Control.Applicative
 import System.Environment
 import Text.Printf
 import Data.Foldable (toList)
-import Text.Megaparsec (setInput, anySingle, satisfy, parse, Parsec, eof)
+import Text.Megaparsec (setInput, anySingle, satisfy, parse, Parsec, eof, sepBy)
 import Text.Megaparsec.Char (newline)
 import Text.Megaparsec.Char.Lexer (decimal, signed)
 import Text.Megaparsec.Error (errorBundlePretty)

execs/Day02.hs

@@ -0,0 +1,55 @@
+{-# Options_GHC -w #-}
+{-# Language OverloadedStrings #-}
+{-|
+Module      : Main
+Description : Day 2 solution
+Copyright   : (c) Eric Mertens, 2019
+License     : ISC
+Maintainer  : [email protected]
+
+<https://adventofcode.com/2019/day/2>
+
+-}
+module Main (main) where
+
+import Advent
+import Data.IntMap (IntMap)
+import qualified Data.IntMap as IntMap
+
+type Program = IntMap Int
+
+(!) :: Program -> Int -> Int
+(!) = (IntMap.!)
+
+newProgram :: [Int] -> Program
+newProgram = IntMap.fromList . zip [0..]
+
+main :: IO ()
+main =
+  do inp <- getParsedInput 2 (number `sepBy` ",")
+     let pgm = newProgram inp
+     print (startup 12 2 pgm)
+     print (head [ 100 * noun + verb
+                 | noun <- [0..99]
+                 , verb <- [0..99]
+                 , startup noun verb pgm == 19690720 ])
+
+-- | Run the given program after assigning the given noun and verb.
+startup :: Int {- ^ noun -} -> Int {- ^ verb -} -> Program -> Int
+startup noun verb
+  = run 0
+  . IntMap.insert 1 noun
+  . IntMap.insert 2 verb
+
+-- | Run the given program starting at the given program counter
+-- returning the initial memory value once the program halts.
+run :: Int {- ^ program counter -} -> Program -> Int
+run i pgm =
+  case arg 0 of
+    1  -> math (+)
+    2  -> math (*)
+    99 -> pgm ! 0
+  where
+    math f = run (i+4) (IntMap.insert (arg 3) (val 1 `f` val 2) pgm)
+    val j = pgm ! arg j
+    arg j = pgm ! (i+j)

inputs/input02.txt

@@ -0,0 +1 @@
+1,0,0,3,1,1,2,3,1,3,4,3,1,5,0,3,2,13,1,19,1,19,10,23,1,23,13,27,1,6,27,31,1,9,31,35,2,10,35,39,1,39,6,43,1,6,43,47,2,13,47,51,1,51,6,55,2,6,55,59,2,59,6,63,2,63,13,67,1,5,67,71,2,9,71,75,1,5,75,79,1,5,79,83,1,83,6,87,1,87,6,91,1,91,5,95,2,10,95,99,1,5,99,103,1,10,103,107,1,107,9,111,2,111,10,115,1,115,9,119,1,13,119,123,1,123,9,127,1,5,127,131,2,13,131,135,1,9,135,139,1,2,139,143,1,13,143,0,99,2,0,14,0