feat: Add default configuration for KCL language server

Author: arichtman

Diff for: book/src/generated/lang-support.md

@@ -119,6 +119,7 @@
 | jsx | ✓ | ✓ | ✓ | `typescript-language-server` |
 | julia | ✓ | ✓ | ✓ | `julia` |
 | just | ✓ | ✓ | ✓ |  |
+| kcl |  |  |  | `kcl-language-server` |
 | kdl | ✓ | ✓ | ✓ |  |
 | koka | ✓ |  | ✓ | `koka` |
 | kotlin | ✓ | ✓ | ✓ | `kotlin-language-server` |

Diff for: languages.toml

@@ -57,6 +57,7 @@ jedi = { command = "jedi-language-server" }
 jq-lsp = { command = "jq-lsp" }
 jsonnet-language-server = { command = "jsonnet-language-server", args= ["-t", "--lint"] }
 julia = { command = "julia", timeout = 60, args = [ "--startup-file=no", "--history-file=no", "--quiet", "-e", "using LanguageServer; runserver()", ] }
+kcl-language-server = { command = "kcl-language-server" }
 koka = { command = "koka", args = ["--language-server", "--lsstdio"] }
 koto-ls = { command = "koto-ls" }
 kotlin-language-server = { command = "kotlin-language-server" }
@@ -4254,3 +4255,14 @@ indent = { tab-width = 2, unit = "  " }
 [[grammar]]
 name = "werk"
 source = { git = "https://github.com/little-bonsai/tree-sitter-werk", rev = "92b0f7fe98465c4c435794a58e961306193d1c1e" }
+
+[[language]]
+name = "kcl"
+scope = "source.k"
+file-types = ["kcl", { glob = "*.k" } ]
+roots = ["kcl.mod", "kcl.yaml"]
+language-servers = ["kcl-language-server"]
+
+[[grammar]]
+name = "kcl"
+source = { git = "https://github.com/kcl-lang/tree-sitter-kcl", rev = "b0b2eb38009e04035a6e266c7e11e541f3caab7c" }

Diff for: runtime/queries/kcl/highlights.scm

@@ -0,0 +1,166 @@
+(identifier) @variable
+
+; Reset highlighting in string interpolations
+(interpolation) @none
+
+(import_stmt
+  (dotted_name
+    (identifier) @namespace))
+
+(import_stmt
+  (dotted_name
+    (identifier) @namespace)
+  (identifier) @namespace)
+
+(basic_type) @type
+
+(schema_type
+  (dotted_name
+    (identifier) @type))
+
+(schema_type
+  (dotted_name
+    (identifier) @namespace
+    (identifier) @type))
+
+(schema_expr
+  (identifier) @type)
+
+(protocol_stmt
+  (identifier) @type)
+
+(rule_stmt
+    (identifier) @type)
+
+(schema_stmt
+  (identifier) @type)
+
+(lambda_expr
+  (typed_parameter (identifier) @parameter))
+
+(lambda_expr
+  (identifier) @parameter)
+
+(selector_expr
+  (select_suffix
+    (identifier) @property))
+
+(comment) @comment
+(string) @string
+(escape_sequence) @string.escape
+
+(schema_stmt
+  body: (block
+    .
+    (string
+      (string_content) @string.documentation)))
+
+(decorator
+  (identifier) @attribute)
+
+(call_expr
+  function: (identifier) @function)
+
+(call_expr
+  function: (selector_expr
+    (select_suffix
+      (identifier) @function)))
+
+[
+  (integer)
+  (float)
+] @number
+
+[
+  (true)
+  (false)
+  (none)
+  (undefined)
+] @constant.builtin
+
+[
+  "all"
+  "any"
+  "assert"
+  "as"
+  "check"
+  "elif"
+  "else"
+  "filter"
+  "for"
+  "if"
+  "import"
+  "lambda"
+  "map"
+  "mixin"
+  "protocol"
+  "rule"
+  "schema"
+  "type"
+] @keyword
+
+[
+  "("
+  ")"
+  "["
+  "]"
+  "{"
+  "}"
+] @punctuation.bracket
+
+(interpolation
+  "${" @punctuation.special
+  "}" @punctuation.special)
+
+[
+  "+"
+  "-"
+  "*"
+  "**"
+  "/"
+  "//"
+  "%"
+  "<<"
+  ">>"
+  "&"
+  "|"
+  "^"
+  "<"
+  ">"
+  "~"
+  "<="
+  ">="
+  "=="
+  "!="
+  "@"
+  "and"
+  "or"
+  "not"
+  "in"
+  "is"
+  "="
+  ":"
+] @operator
+
+; second argument is a regex in all regex functions with at least two arguments
+(call_expr
+  function: (selector_expr
+    (identifier) @_regex)
+  arguments: (argument_list
+    (_)
+    .
+    (string
+      (string_content) @string.regexp))
+  (#eq? @_regex "regex"))
+
+; first argument is a regex in 'regex.compile' function
+(call_expr
+  .
+  function: (selector_expr
+    (identifier) @_regex
+    (select_suffix
+      (identifier) @_fn (#eq? @_fn "compile")))
+  arguments: (argument_list
+    (string
+      (string_content) @string.regexp))
+  (#eq? @_regex "regex"))