Add iced#paredit#get_current_top_object

Author: liquidz

autoload/iced/paredit.vim

@@ -90,6 +90,68 @@ function! iced#paredit#move_to_parent_element() abort
   return col('.')
 endfunction
 
+function! s:is_in_range(current_pos, start_pos, end_pos) abort
+  return (a:current_pos[1] == a:start_pos[1] && a:start_pos[2] <= a:current_pos[2])
+        \ || (a:current_pos[1] == a:end_pos[1] && a:current_pos[2] <= a:end_pos[2])
+        \ || (a:start_pos[1] <= a:current_pos[1] && a:current_pos[1] <= a:end_pos[1])
+endfunction
+
+function! iced#paredit#get_current_top_object_raw(...) abort
+  let open_char = get(a:, 1, '(')
+  let close_char = get(a:, 2, ')')
+  let pos = getcurpos()
+  let result = {}
+
+  try
+    while v:true
+      let line = getline('.')
+      if empty(line) | break | endif
+
+      if substitute(line, '^#[^\(\[\{ ]\+ \?', '', '')[0] ==# open_char
+        let start_pos = getcurpos()
+        let start_pos[2] = stridx(line, open_char) + 1
+
+        call setpos('.', start_pos)
+        " move to pair
+        silent normal! %
+        let end_pos = getcurpos()
+
+        if s:is_in_range(pos, start_pos, end_pos)
+          call setpos('.', start_pos)
+          " NOTE: `o0y` is to wrap top level tag literal
+          silent exe printf('normal! va%so0y', open_char)
+
+          let result = {
+               \ 'code': @@,
+               \ 'pos': start_pos,
+               \ }
+          break
+        endif
+      endif
+
+      if line('.') == 1 | break | endif
+      " Move cursor up
+      silent normal! k
+    endwhile
+  finally
+    silent exe "normal! \<Esc>"
+  endtry
+
+  return result
+endfunction
+
+function! iced#paredit#get_current_top_object(...) abort
+  let view = winsaveview()
+  let reg_save = @@
+
+  try
+    return call('iced#paredit#get_current_top_object_raw', a:000)
+  finally
+    let @@ = reg_save
+    call winrestview(view)
+  endtry
+endfunction
+
 function! iced#paredit#get_current_top_list_raw(...) abort
   let code = ''
   let pos = ''

test/paredit.vim

@@ -169,3 +169,64 @@ function! s:suite.find_parent_form_raw_test() abort
 
   call s:buf.stop_dummy()
 endfunction
+
+function! s:suite.get_current_top_object_test() abort
+  call s:buf.start_dummy([
+        \ '(foo',
+        \ ' (bar|))',
+        \ ])
+  let res = iced#paredit#get_current_top_object()
+  call s:assert.equals(res['code'], "(foo\n (bar))")
+  call s:buf.stop_dummy()
+
+  " with meta
+  call s:buf.start_dummy([
+        \ '#tag1/name (foo',
+        \ ' (bar|))',
+        \ ])
+  let res = iced#paredit#get_current_top_object()
+  call s:assert.equals(res['code'], "#tag1/name (foo\n (bar))")
+  call s:buf.stop_dummy()
+endfunction
+
+function! s:suite.get_current_top_object_vector_test() abort
+  call s:buf.start_dummy([
+       \ '[foo',
+       \ ' [bar|]]',
+       \ ])
+  let res = iced#paredit#get_current_top_object()
+  call s:assert.equals(res, {})
+  let res = iced#paredit#get_current_top_object('[', ']')
+  call s:assert.equals(res['code'], "[foo\n [bar]]")
+  call s:buf.stop_dummy()
+
+  " with meta
+  call s:buf.start_dummy([
+       \ '#tag2/name [foo',
+       \ ' [bar|]]',
+       \ ])
+  let res = iced#paredit#get_current_top_object('[', ']')
+  call s:assert.equals(res['code'], "#tag2/name [foo\n [bar]]")
+  call s:buf.stop_dummy()
+endfunction
+
+function! s:suite.get_current_top_object_vector_test() abort
+  call s:buf.start_dummy([
+       \ '{:foo',
+       \ ' {:bar 123|}}',
+       \ ])
+  let res = iced#paredit#get_current_top_object()
+  call s:assert.equals(res, {})
+  let res = iced#paredit#get_current_top_object('{', '}')
+  call s:assert.equals(res['code'], "{:foo\n {:bar 123}}")
+  call s:buf.stop_dummy()
+
+  " with meta
+  call s:buf.start_dummy([
+       \ '#tag3/name {:foo',
+       \ ' {:bar 123|}}',
+       \ ])
+  let res = iced#paredit#get_current_top_object('{', '}')
+  call s:assert.equals(res['code'], "#tag3/name {:foo\n {:bar 123}}")
+  call s:buf.stop_dummy()
+endfunction